build: Update version to 2.0.1
[iotivity.git] / service / easy-setup / sampleapp / enrollee / tizen-sdb / EnrolleeSample / SConscript
1 ##########################################################################
2 #
3 # Copyright 2015 Samsung Electronics All Rights Reserved.
4 #
5 #
6 #
7 # Licensed under the Apache License, Version 2.0 (the "License");
8 # you may not use this file except in compliance with the License.
9 # You may obtain a copy of the License at
10 #
11 #      http://www.apache.org/licenses/LICENSE-2.0
12 #
13 # Unless required by applicable law or agreed to in writing, software
14 # distributed under the License is distributed on an "AS IS" BASIS,
15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
16 # See the License for the specific language governing permissions and
17 # limitations under the License.
18 #
19 ##########################################################################
20
21 ##
22 # This script includes generic build options:
23 #    release/debug, target os, target arch, cross toolchain, build environment etc
24 #
25 # Note to maintainers: this script borrows elements from the top-level 
26 # build_common/SConscript. The borrowed elements should be kept in sync, 
27 # but there is no current way to do that automatically.
28 # Since it appears in a target-themed directory (tizen-sdb), it is not
29 # clear that it ought to borrow quite so much.
30 ##
31 import os
32 import platform
33
34 project_version = '2.0.1'
35
36 # Map of host os and allowed target os (host: allowed target os)
37 host_target_map = {
38     'linux': ['linux', 'android', 'yocto', 'tizen'],
39     'windows': ['windows', 'android'],
40     'darwin': ['darwin', 'ios', 'android'],
41     'msys_nt': ['msys_nt'],
42 }
43
44 # Map of os and allowed archs (os: allowed archs)
45 os_arch_map = {
46     'linux': [
47         'x86', 'x86_64', 'arm', 'arm-v7a', 'armeabi-v7a', 'arm64', 'mips',
48         'mipsel', 'mips64', 'mips64el', 'i386', 'powerpc', 'sparc', 'aarch64'
49     ],
50     'tizen': ['x86', 'x86_64', 'arm', 'arm-v7a', 'armeabi-v7a', 'arm64'],
51     'android': [
52         'x86', 'x86_64', 'armeabi', 'armeabi-v7a', 'armeabi-v7a-hard',
53         'arm64-v8a'
54     ],
55     'windows': ['x86', 'amd64', 'arm'],
56     'msys_nt': ['x86', 'x86_64'],
57     'darwin': ['i386', 'x86_64'],
58     'ios': ['i386', 'x86_64', 'armv7', 'armv7s', 'arm64'],
59     'yocto': [
60         'i586', 'i686', 'x86_64', 'arm', 'aarch64', 'powerpc', 'powerpc64',
61         'mips', 'mipsel'
62     ],
63 }
64
65 host = platform.system().lower()
66
67 # the host string contains version of windows. 6.3, 6.4, 10.0 which is 8.0, 8.1, and 10 respectively.
68 # Let's canonicalize the msys_nt-XX.X system name by stripping version off.
69 if 'msys_nt' in host:
70     host = 'msys_nt'
71
72 if host not in host_target_map:
73     msg = "\nError: Current system (%s) is not supported\n" % host
74     Exit(msg)
75
76 ######################################################################
77 # Get build options (the optins from command line)
78 ######################################################################
79 target_os = ARGUMENTS.get('TARGET_OS', host).lower()  # target os
80
81 if target_os not in host_target_map[host]:
82     msg = "\nError: Unsupported target os: %s (supported values: %s)\n" % (
83         target_os, host_target_map[host])
84     Exit(msg)
85
86 if target_os == 'android':
87     default_arch = 'x86'
88 else:
89     default_arch = platform.machine()
90     if target_os == 'windows':
91         default_arch = default_arch.lower()
92
93 target_arch = ARGUMENTS.get('TARGET_ARCH', default_arch)  # target arch
94
95 # True if binary needs to be installed on board. (Might need root permissions)
96 # set to 'no', 'false' or 0 for only compilation
97 require_upload = ARGUMENTS.get('UPLOAD', False)
98
99 default_with_upstream_libcoap = 0
100
101 if ARGUMENTS.get('TEST'):
102     logging_default = False
103 else:
104     release_mode = False
105     if ARGUMENTS.get('RELEASE', True) in [
106             'y', 'yes', 'true', 't', '1', 'on', 'all', True
107     ]:
108         release_mode = True
109     logging_default = (release_mode == False)
110
111 ######################################################################
112 # Common build options (release, target os, target arch)
113 ######################################################################
114 help_vars = Variables()
115
116 help_vars.Add('PROJECT_VERSION', 'The version of IoTivity', project_version)
117
118 help_vars.Add(BoolVariable('VERBOSE', 'Show compilation', False))
119 help_vars.Add(BoolVariable('RELEASE', 'Build for release?',
120                            True))  # set to 'no', 'false' or 0 for debug
121 help_vars.Add(
122     EnumVariable('TARGET_OS', 'Target platform', host, host_target_map[host]))
123
124 help_vars.Add(BoolVariable('WITH_TCP', 'Build with TCP adapter', False))
125 help_vars.Add(BoolVariable('WITH_PROXY', 'Build with CoAP-HTTP Proxy', False))
126 help_vars.Add(
127     ListVariable('WITH_MQ', 'Build with MQ publisher/broker', 'OFF',
128                  ['OFF', 'SUB', 'PUB', 'BROKER']))
129 help_vars.Add(
130     BoolVariable(
131         'WITH_CLOUD',
132         'Build including AccountManager class and Cloud Client sample', False))
133 help_vars.Add(
134     ListVariable('RD_MODE', 'Resource Directory build mode', 'CLIENT',
135                  ['CLIENT', 'SERVER']))
136
137 help_vars.Add(BoolVariable('SIMULATOR', 'Build with simulator module', False))
138
139 help_vars.Add(
140     ListVariable('TARGET_TRANSPORT', 'Target transport', 'ALL',
141                  ['ALL', 'BT', 'BLE', 'IP', 'NFC']))
142
143 help_vars.Add(
144     EnumVariable('TARGET_ARCH', 'Target architecture', default_arch,
145                  os_arch_map[target_os]))
146 help_vars.Add(
147     EnumVariable(
148         'SECURED', 'Build with DTLS', '1', allowed_values=('0', '1')))
149 help_vars.Add(
150     EnumVariable(
151         'MULTIPLE_OWNER',
152         'Enable multiple owner',
153         '0',
154         allowed_values=('0', '1')))
155 help_vars.Add(
156     EnumVariable(
157         'EXC_PROV_SUPPORT',
158         'Except OCPMAPI library(libocpmapi.so)',
159         '0',
160         allowed_values=('0', '1')))
161 help_vars.Add(
162     EnumVariable('TEST', 'Run unit tests', '0', allowed_values=('0', '1')))
163 help_vars.Add(BoolVariable('LOGGING', 'Enable stack logging', logging_default))
164 help_vars.Add(
165     EnumVariable(
166         'LOG_LEVEL',
167         'Enable stack logging level',
168         'DEBUG',
169         allowed_values=('DEBUG', 'INFO', 'ERROR', 'WARNING', 'FATAL')))
170 help_vars.Add(
171     EnumVariable(
172         'ROUTING', 'Enable routing', 'EP', allowed_values=('GW', 'EP')))
173 help_vars.Add(
174     EnumVariable(
175         'BUILD_SAMPLE',
176         'Build with sample',
177         'ON',
178         allowed_values=('ON', 'OFF')))
179 help_vars.Add(
180     PathVariable('ANDROID_NDK', 'Android NDK path', None,
181                  PathVariable.PathAccept))
182 help_vars.Add(
183     PathVariable('ANDROID_HOME', 'Android SDK path', None,
184                  PathVariable.PathAccept))
185 help_vars.Add(
186     PathVariable('ANDROID_GRADLE', 'Gradle binary file', None,
187                  PathVariable.PathIsFile))
188 help_vars.Add(
189     EnumVariable(
190         'WITH_UPSTREAM_LIBCOAP',
191         'Use latest stable version of LibCoAP downloaded from github',
192         default_with_upstream_libcoap,
193         allowed_values=('0', '1')))
194 help_vars.Add(
195     BoolVariable('WITH_ENV', 'Use compiler options from environment', False))
196
197 if target_os == 'windows':
198     # For VS2013, MSVC_VERSION is '12.0'. For VS2015, MSVC_VERSION is '14.0'.
199     # Default value is None, meaning that SCons has to choose automatically a VS version.
200     help_vars.Add(
201         EnumVariable(
202             'MSVC_VERSION',
203             'MSVC compiler version - Windows',
204             None,
205             allowed_values=('12.0', '14.0')))
206
207 help_vars.Add(BoolVariable('BUILD_JAVA', 'Build Java bindings', False))
208 help_vars.Add(
209     PathVariable('JAVA_HOME', 'JDK directory',
210                  os.environ.get('JAVA_HOME'), PathVariable.PathAccept))
211 help_vars.Add(
212     EnumVariable(
213         'OIC_SUPPORT_TIZEN_TRACE',
214         'Tizen Trace(T-trace) api availability',
215         'False',
216         allowed_values=('True', 'False')))
217
218 AddOption(
219     '--prefix',
220     dest='prefix',
221     type='string',
222     nargs=1,
223     action='store',
224     metavar='DIR',
225     help='installation prefix')
226
227 ######################################################################
228 # Platform(build target) specific options: SDK/NDK & toolchain
229 ######################################################################
230 targets_support_cc = ['linux', 'tizen']
231
232 if target_os in targets_support_cc:
233     # Set cross compile toolchain
234     help_vars.Add(
235         'TC_PREFIX',
236         "Toolchain prefix (Generally only be required for cross-compiling)",
237         os.environ.get('TC_PREFIX'))
238     help_vars.Add(
239         PathVariable(
240             'TC_PATH',
241             'Toolchain path (Generally only be required for cross-compiling)',
242             os.environ.get('TC_PATH')))
243
244 if target_os in ['android']:
245     # Android always uses GNU compiler regardless of the host
246     env = Environment(
247         variables=help_vars,
248         tools=['gnulink', 'gcc', 'g++', 'ar', 'as', 'textfile'])
249 else:
250     env = Environment(
251         variables=help_vars,
252         tools=['default', 'textfile'],
253         TARGET_ARCH=target_arch,
254         TARGET_OS=target_os,
255         PREFIX=GetOption('prefix'),
256         LIB_INSTALL_DIR=ARGUMENTS.get('LIB_INSTALL_DIR')  #for 64bit build
257     )
258 Help(help_vars.GenerateHelpText(env))
259
260 if env.get('WITH_ENV'):
261     env['ENV'] = os.environ
262     if 'CC' in os.environ:
263         env['CC'] = Split(os.environ['CC'])
264         print("using CC from environment: %s" % env['CC'])
265     if 'CXX' in os.environ:
266         env['CXX'] = Split(os.environ['CXX'])
267         print("using CXX from environment: %s" % env['CXX'])
268     if 'CFLAGS' in os.environ:
269         env['CFLAGS'] = Split(os.environ['CFLAGS'])
270         print("using CFLAGS from environment: %s" % env['CFLAGS'])
271     if 'CXXFLAGS' in os.environ:
272         env['CXXFLAGS'] = Split(os.environ['CXXFLAGS'])
273         print("using CXXFLAGS from environment: %s" % env['CXXFLAGS'])
274     if 'CCFLAGS' in os.environ:
275         env['CCFLAGS'] = Split(os.environ['CCFLAGS'])
276         print("using CCFLAGS from environment: %s" % env['CCFLAGS'])
277     if 'CPPFLAGS' in os.environ:
278         env['CPPFLAGS'] = Split(os.environ['CPPFLAGS'])
279         print("using CPPFLAGS from environment: %s" % env['CPPFLAGS'])
280     if 'LDFLAGS' in os.environ:
281         env['LINKFLAGS'] = Split(os.environ['LDFLAGS'])
282         print("using LDFLAGS/LINKFLAGS from environment: %s" % env['LINKFLAGS'])
283
284 tc_set_msg = '''
285 ************************************ Warning **********************************
286 *   Environment variable TC_PREFIX/TC_PATH is set. It will change the default *
287 * toolchain, if it isn't what you expect you should unset it, otherwise it may*
288 * cause inexplicable errors.                                                  *
289 *******************************************************************************
290 '''
291 if env.get('VERBOSE') == False:
292     env['CCCOMSTR'] = "Compiling $TARGET"
293     env['SHCCCOMSTR'] = "Compiling $TARGET"
294     env['CXXCOMSTR'] = "Compiling $TARGET"
295     env['SHCXXCOMSTR'] = "Compiling $TARGET"
296     env['LINKCOMSTR'] = "Linking $TARGET"
297     env['SHLINKCOMSTR'] = "Linking $TARGET"
298     env['ARCOMSTR'] = "Archiving $TARGET"
299     env['RANLIBCOMSTR'] = "Indexing Archive $TARGET"
300
301 if target_os in targets_support_cc:
302     prefix = env.get('TC_PREFIX')
303     tc_path = env.get('TC_PATH')
304     if prefix:
305         env.Replace(CC=prefix + env.get('CC', 'gcc'))
306         env.Replace(CXX=prefix + env.get('CXX', 'g++'))
307         env.Replace(AR=prefix + env.get('AR', 'ar'))
308         env.Replace(AS=prefix + env.get('AS', 'as'))
309         env.Replace(RANLIB=prefix + env.get('RANLIB', 'ranlib'))
310
311     if tc_path:
312         env.PrependENVPath('PATH', tc_path)
313         sys_root = os.path.abspath(tc_path + '/../')
314         env.AppendUnique(CCFLAGS=['--sysroot=' + sys_root])
315         env.AppendUnique(LINKFLAGS=['--sysroot=' + sys_root])
316
317     if prefix or tc_path:
318         print(tc_set_msg)
319
320 # Import env variables only if reproductibility is ensured
321 if target_os in ['yocto']:
322     env['CONFIG_ENVIRONMENT_IMPORT'] = True
323 else:
324     env['CONFIG_ENVIRONMENT_IMPORT'] = False
325
326 if env['CONFIG_ENVIRONMENT_IMPORT'] == True:
327     print("warning: importing some environment variables for OS: %s" % target_os)
328     for ev in [
329             'PATH', 'PKG_CONFIG', 'PKG_CONFIG_PATH', 'PKG_CONFIG_SYSROOT_DIR'
330     ]:
331         if os.environ.get(ev) != None:
332             env['ENV'][ev] = os.environ.get(ev)
333     if os.environ['LDFLAGS'] != None:
334         env.AppendUnique(LINKFLAGS=Split(os.environ['LDFLAGS']))
335
336 # Ensure scons be able to change its working directory
337 env.SConscriptChdir(1)
338
339 # Set the source directory and build directory
340 #   Source directory: 'dir'
341 #   Build directory: 'dir'/out/<target_os>/<target_arch>/<release or debug>/
342 #
343 # You can get the directory as following:
344 #   env.get('SRC_DIR')
345 #   env.get('BUILD_DIR')
346
347
348 def __set_dir(env, dir):
349     if not os.path.exists(dir + '/SConstruct'):
350         msg = '''
351 *************************************** Error *********************************
352 * The directory(%s) seems isn't a source code directory, no SConstruct file is
353 * found. *
354 *******************************************************************************
355 ''' % dir
356         Exit(msg)
357
358     if env.get('RELEASE'):
359         build_dir = dir + '/out/' + target_os + '/' + target_arch + '/release/'
360     else:
361         build_dir = dir + '/out/' + target_os + '/' + target_arch + '/debug/'
362     env.VariantDir(build_dir, dir, duplicate=0)
363
364     env.Replace(BUILD_DIR=build_dir)
365     env.Replace(SRC_DIR=dir)
366
367
368 def __src_to_obj(env, src, home=''):
369     obj = env.get('BUILD_DIR') + src.replace(home, '')
370     if env.get('OBJSUFFIX'):
371         obj += env.get('OBJSUFFIX')
372     return env.Object(obj, src)
373
374
375 def __install(ienv, targets, name):
376     i_n = ienv.Install(env.get('BUILD_DIR'), targets)
377     Alias(name, i_n)
378     env.AppendUnique(TS=[name])
379
380
381 def __installlib(ienv, targets, name):
382     user_prefix = env.get('PREFIX')
383     if user_prefix:
384         user_lib = env.get('LIB_INSTALL_DIR')
385         if user_lib:
386             i_n = ienv.Install(user_lib, targets)
387         else:
388             i_n = ienv.Install(user_prefix + '/lib', targets)
389         ienv.Alias("install", i_n)
390     else:
391         i_n = ienv.Install(env.get('BUILD_DIR'), targets)
392     ienv.Alias("install", i_n)
393
394
395 def __installbin(ienv, targets, name):
396     user_prefix = env.get('PREFIX')
397     if user_prefix:
398         i_n = ienv.Install(user_prefix + '/bin', targets)
399         ienv.Alias("install", i_n)
400
401
402 def __installheader(ienv, targets, dir, name):
403     user_prefix = env.get('PREFIX')
404     if user_prefix:
405         i_n = ienv.Install(user_prefix + '/include/' + dir, targets)
406     else:
407         i_n = ienv.Install(
408             os.path.join(env.get('BUILD_DIR'), 'include', dir), targets)
409     ienv.Alias("install", i_n)
410
411
412 def __installpcfile(ienv, targets, name):
413     user_prefix = env.get('PREFIX')
414     if user_prefix:
415         user_lib = env.get('LIB_INSTALL_DIR')
416         if user_lib:
417             i_n = ienv.Install(user_lib + '/pkgconfig', targets)
418         else:
419             i_n = ienv.Install(user_prefix + '/lib/pkgconfig', targets)
420     else:
421         i_n = ienv.Install(env.get('BUILD_DIR') + 'lib/pkgconfig', targets)
422     ienv.Alias("install", i_n)
423
424
425 def __append_target(ienv, name, targets=None):
426     if targets:
427         env.Alias(name, targets)
428     env.AppendUnique(TS=[name])
429
430
431 def __print_targets(env):
432     Help('''
433 ===============================================================================
434 Targets:\n    ''')
435     for t in env.get('TS'):
436         Help(t + ' ')
437     Help('''
438 \nDefault all targets will be built. You can specify the target to build:
439
440     $ scons [options] [target]
441 ===============================================================================
442 ''')
443
444
445 env.AddMethod(__set_dir, 'SetDir')
446 env.AddMethod(__print_targets, 'PrintTargets')
447 env.AddMethod(__src_to_obj, 'SrcToObj')
448 env.AddMethod(__append_target, 'AppendTarget')
449 env.AddMethod(__install, 'InstallTarget')
450 env.AddMethod(__installlib, 'UserInstallTargetLib')
451 env.AddMethod(__installbin, 'UserInstallTargetBin')
452 env.AddMethod(__installheader, 'UserInstallTargetHeader')
453 env.AddMethod(__installpcfile, 'UserInstallTargetPCFile')
454 env.SetDir(env.GetLaunchDir())
455 env['ROOT_DIR'] = env.GetLaunchDir() + '/..'
456
457 Export('env')
458
459 ######################################################################
460 # Scons to generate the iotivity.pc file from iotivity.pc.in file
461 ######################################################################
462 pc_file = env.get('SRC_DIR') + '/iotivity.pc.in'
463
464 user_prefix = env.get('PREFIX')
465 user_lib = env.get('LIB_INSTALL_DIR')
466
467 if not user_prefix:
468     user_prefix = env.get('BUILD_DIR').encode('string_escape')
469
470 if not user_lib:
471     user_lib = '$${prefix}/lib'
472
473 defines = []
474 if env.get('LOGGING'):
475     defines.append('-DTB_LOG=1')
476
477 if env.get('ROUTING') == 'GW':
478     defines.append('-DROUTING_GATEWAY=1')
479 elif env.get('ROUTING') == 'EP':
480     defines.append('-DROUTING_EP=1')
481
482 libs = []
483 if env.get('WITH_TCP'):
484     defines.append('-DTCP_ADAPTER=1')
485     if env.get('SECURED') == '1':
486         defines.append('-D__WITH_TLS__=1')
487
488 if env.get('SECURED') == '1':
489     defines.append('-D__WITH_DTLS__=1')
490     if env.get('EXC_PROV_SUPPORT') == '0':
491         libs.append('-locpmapi')
492
493 pc_vars = {
494     '\@VERSION\@': project_version,
495     '\@PREFIX\@': user_prefix,
496     '\@EXEC_PREFIX\@': user_prefix,
497     '\@LIB_INSTALL_DIR\@': user_lib,
498     '\@DEFINES\@': " ".join(defines),
499     '\@LIBS\@': " ".join(libs)
500 }
501
502 env.Substfile(pc_file, SUBST_DICT=pc_vars)
503
504 ######################################################################
505 # Setting global compiler flags
506 ######################################################################
507 target_transport = env.get('TARGET_TRANSPORT')
508 with_mq = env.get('WITH_MQ')
509 with_ra = env.get('WITH_RA')
510 with_tcp = env.get('WITH_TCP')
511 rd_mode = env.get('RD_MODE')
512 with_ra_ibb = env.get('WITH_RA_IBB')
513
514 env.AppendUnique(LIBPATH=[env.get('BUILD_DIR')])
515
516 if (env.get('WITH_UPSTREAM_LIBCOAP') == '1'):
517     env.AppendUnique(CPPDEFINES=['WITH_UPSTREAM_LIBCOAP'])
518
519 if (target_os not in ['windows']):
520     env.AppendUnique(CPPDEFINES=['WITH_POSIX'])
521
522 if (target_os in ['darwin', 'ios']):
523     env.AppendUnique(CPPDEFINES=['_DARWIN_C_SOURCE'])
524
525 if (env.get('SECURED') == '1'):
526     env.AppendUnique(CPPDEFINES=['__WITH_DTLS__'])
527
528 if ((env.get('SECURED') == '1') and with_tcp):
529     env.AppendUnique(CPPDEFINES=['__WITH_TLS__'])
530
531 if (env.get('MULTIPLE_OWNER') == '1'):
532     env.AppendUnique(CPPDEFINES=['MULTIPLE_OWNER'])
533
534 if (env.get('ROUTING') == 'GW'):
535     env.AppendUnique(CPPDEFINES=['ROUTING_GATEWAY'])
536 elif (env.get('ROUTING') == 'EP'):
537     env.AppendUnique(CPPDEFINES=['ROUTING_EP'])
538
539 if (('IP' in target_transport) or ('ALL' in target_transport)):
540     env.AppendUnique(CPPDEFINES=['WITH_BWT'])
541
542 if (target_os in ['linux', 'tizen', 'android'] and with_tcp):
543     env.AppendUnique(CPPDEFINES=['WITH_TCP'])
544
545 if (target_os in ['linux', 'tizen', 'android', 'ios']):
546     if (('BLE' in target_transport) or ('BT' in target_transport) or
547         ('ALL' in target_transport)):
548         env.AppendUnique(CPPDEFINES=['WITH_TCP'])
549
550 if 'ALL' in target_transport:
551     if with_ra:
552         env.AppendUnique(CPPDEFINES=['RA_ADAPTER'])
553     if with_tcp:
554         env.AppendUnique(CPPDEFINES=['TCP_ADAPTER'])
555     if (target_os in ['linux', 'yocto']):
556         env.AppendUnique(
557             CPPDEFINES=['IP_ADAPTER', 'NO_EDR_ADAPTER', 'LE_ADAPTER'])
558     elif (target_os == 'android'):
559         env.AppendUnique(CPPDEFINES=[
560             'IP_ADAPTER', 'EDR_ADAPTER', 'LE_ADAPTER', 'NFC_ADAPTER'
561         ])
562     elif (target_os in ['darwin', 'ios', 'msys_nt', 'windows']):
563         env.AppendUnique(
564             CPPDEFINES=['IP_ADAPTER', 'NO_EDR_ADAPTER', 'NO_LE_ADAPTER'])
565     else:
566         env.AppendUnique(
567             CPPDEFINES=['IP_ADAPTER', 'EDR_ADAPTER', 'LE_ADAPTER'])
568 else:
569     if ('BT' in target_transport):
570         if (target_os == 'linux'):
571             msg = "CA Transport BT is not supported "
572             Exit(msg)
573         else:
574             env.AppendUnique(CPPDEFINES=['EDR_ADAPTER'])
575     else:
576         env.AppendUnique(CPPDEFINES=['NO_EDR_ADAPTER'])
577
578     if ('BLE' in target_transport):
579         env.AppendUnique(CPPDEFINES=['LE_ADAPTER'])
580     else:
581         env.AppendUnique(CPPDEFINES=['NO_LE_ADAPTER'])
582
583     if ('IP' in target_transport):
584         env.AppendUnique(CPPDEFINES=['IP_ADAPTER'])
585     else:
586         env.AppendUnique(CPPDEFINES=['NO_IP_ADAPTER'])
587
588     if with_tcp:
589         if (target_os in [
590                 'linux', 'tizen', 'android', 'ios', 'windows'
591         ]):
592             env.AppendUnique(CPPDEFINES=['TCP_ADAPTER', 'WITH_TCP'])
593         else:
594             msg = "CA Transport TCP is not supported "
595             Exit(msg)
596     else:
597         env.AppendUnique(CPPDEFINES=['NO_TCP_ADAPTER'])
598
599     if ('NFC' in target_transport):
600         if (target_os == 'android'):
601             env.AppendUnique(CPPDEFINES=['NFC_ADAPTER'])
602         else:
603             msg = "CA Transport NFC is not supported "
604             Exit(msg)
605     else:
606         env.AppendUnique(CPPDEFINES=['NO_NFC_ADAPTER'])
607
608 if ('SUB' in with_mq):
609     env.AppendUnique(CPPDEFINES=['MQ_SUBSCRIBER', 'WITH_MQ'])
610
611 if ('PUB' in with_mq):
612     env.AppendUnique(CPPDEFINES=['MQ_PUBLISHER', 'WITH_MQ'])
613
614 if ('BROKER' in with_mq):
615     env.AppendUnique(CPPDEFINES=['MQ_BROKER', 'WITH_MQ'])
616
617 if env.get('LOGGING'):
618     env.AppendUnique(CPPDEFINES=['TB_LOG'])
619
620 if env.get('WITH_CLOUD') and with_tcp:
621     env.AppendUnique(CPPDEFINES=['WITH_CLOUD'])
622
623 if 'CLIENT' in rd_mode:
624     env.AppendUnique(CPPDEFINES=['RD_CLIENT'])
625
626 if 'SERVER' in rd_mode:
627     env.AppendUnique(CPPDEFINES=['RD_SERVER'])
628
629 if with_ra_ibb:
630     env.AppendUnique(CPPDEFINES=['RA_ADAPTER_IBB'])
631 ######################################################################
632 # Link scons to Yocto cross-toolchain ONLY when target_os is yocto
633 ######################################################################
634 if target_os == "yocto":
635     '''
636     This code injects Yocto cross-compilation tools+flags into scons'
637     build environment in order to invoke the relevant tools while
638     performing a build.
639     '''
640     import os.path
641     try:
642         CC = os.environ['CC']
643         target_prefix = CC.split()[0]
644         target_prefix = target_prefix[:len(target_prefix) - 3]
645         tools = {
646             "CC": target_prefix + "gcc",
647             "CXX": target_prefix + "g++",
648             "AS": target_prefix + "as",
649             "LD": target_prefix + "ld",
650             "GDB": target_prefix + "gdb",
651             "STRIP": target_prefix + "strip",
652             "RANLIB": target_prefix + "ranlib",
653             "OBJCOPY": target_prefix + "objcopy",
654             "OBJDUMP": target_prefix + "objdump",
655             "AR": target_prefix + "ar",
656             "NM": target_prefix + "nm",
657             "M4": "m4",
658             "STRINGS": target_prefix + "strings"
659         }
660         PATH = os.environ['PATH'].split(os.pathsep)
661         for tool in tools:
662             if tool in os.environ:
663                 for path in PATH:
664                     if os.path.isfile(os.path.join(path, tools[tool])):
665                         env[tool] = os.path.join(path, os.environ[tool])
666                         break
667         env['CROSS_COMPILE'] = target_prefix[:len(target_prefix) - 1]
668     except:
669         msg = "ERROR in Yocto cross-toolchain environment"
670         Exit(msg)
671     '''
672     Now reset TARGET_OS to linux so that all linux specific build configurations
673     hereupon apply for the entirety of the build process.
674     '''
675     env['TARGET_OS'] = 'linux'
676     '''
677     We want to preserve debug symbols to allow BitBake to generate both DEBUG and
678     RELEASE packages for OIC.
679     '''
680     env.AppendUnique(CCFLAGS=['-g'])
681     '''
682     Additional flags to pass to the Yocto toolchain.
683     '''
684     if env.get('RELEASE'):
685         env.AppendUnique(CPPDEFINES=['NDEBUG'])
686     env.AppendUnique(CPPDEFINES=['__linux__', '_GNU_SOURCE'])
687     env.AppendUnique(CFLAGS=['-std=gnu99'])
688     env.AppendUnique(CCFLAGS=['-Wall', '-Wextra', '-fPIC'])
689     env.AppendUnique(LIBS=[
690         'dl',
691         'pthread',
692         'uuid'
693     ])
694     Export('env')
695 else:
696     '''
697     If target_os is not Yocto, continue with the regular build process
698     '''
699     # Load config of target os
700     env.SConscript(target_os + '/SConscript')
701
702 # Delete the temp files of configuration
703 if env.GetOption('clean'):
704     dir = env.get('SRC_DIR')
705
706     if os.path.exists(dir + '/config.log'):
707         Execute(Delete(dir + '/config.log'))
708     if os.path.exists(dir + '/.sconsign.dblite'):
709         Execute(Delete(dir + '/.sconsign.dblite'))
710     if os.path.exists(dir + '/.sconf_temp'):
711         Execute(Delete(dir + '/.sconf_temp'))
712
713 ######################################################################
714 # Check for PThreads support
715 ######################################################################
716 import iotivityconfig
717 from iotivityconfig import *
718
719 conf = Configure(
720     env, custom_tests={'CheckPThreadsSupport': iotivityconfig.check_pthreads})
721
722 # Identify whether we have pthreads support, which is necessary for
723 # threading and mutexes.  This will set the environment variable
724 # POSIX_SUPPORTED, 1 if it is supported, 0 otherwise
725 conf.CheckPThreadsSupport()
726
727 env = conf.Finish()
728 ######################################################################
729
730 #env.SConscript('external_libs.scons')
731 Return('env')