ebd1cdb401f00dd9209ad2282510b40fec566323
[iotivity.git] / resource / csdk / security / SConscript
1 # //******************************************************************
2 # //
3 # // Copyright 2015 Intel Mobile Communications GmbH All Rights Reserved.
4 # //
5 # //-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
6 # //
7 # // Licensed under the Apache License, Version 2.0 (the "License");
8 # // you may not use this file except in compliance with the License.
9 # // You may obtain a copy of the License at
10 # //
11 # //      http://www.apache.org/licenses/LICENSE-2.0
12 # //
13 # // Unless required by applicable law or agreed to in writing, software
14 # // distributed under the License is distributed on an "AS IS" BASIS,
15 # // WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
16 # // See the License for the specific language governing permissions and
17 # // limitations under the License.
18 # //
19 # //-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
20 #
21 # libocsrm (static library) build script
22 ##
23
24 Import('env')
25 import os
26
27 lib_env = env.Clone()
28
29 libocsrm_env = lib_env.Clone()
30
31 target_os = libocsrm_env.get('TARGET_OS')
32 # As in the source code, it includes arduino Time library (C++)
33 # It requires compile the .c with g++
34 if target_os == 'arduino':
35         libocsrm_env.Replace(CC = libocsrm_env.get('CXX'))
36         libocsrm_env.Replace(CFLAGS = libocsrm_env.get('CXXFLAGS'))
37
38 ######################################################################
39 # Build flags
40 ######################################################################
41 with_upstream_libcoap = libocsrm_env.get('WITH_UPSTREAM_LIBCOAP')
42 if with_upstream_libcoap == '1':
43         # For bring up purposes only, we manually copy the forked version to where the unforked version is downloaded.
44         libocsrm_env.AppendUnique(CPPPATH = ['#extlibs/libcoap/libcoap/include'])
45 else:
46         # For bring up purposes only, the forked version will live here.
47         libocsrm_env.AppendUnique(CPPPATH = ['../connectivity/lib/libcoap-4.1.1/include'])
48
49 libocsrm_env.PrependUnique(CPPPATH = [
50                 '../../../extlibs/tinydtls/',
51                 '../logger/include',
52                 '../../c_common/ocrandom/include',
53                 '../include',
54                 '../stack/include',
55                 '../stack/include/internal',
56                 '../../oc_logger/include',
57                 '../connectivity/external/inc',
58                 '../connectivity/common/inc',
59                 '../connectivity/inc',
60                 '../connectivity/api',
61                 '../security/include',
62                 '../security/include/internal',
63                 '../security/provisioning/include'
64                 ])
65
66 if target_os not in ['arduino', 'windows']:
67         libocsrm_env.AppendUnique(CPPDEFINES  = ['WITH_POSIX', '_GNU_SOURCE'])
68         libocsrm_env.AppendUnique(CFLAGS = ['-std=c99', '-Wall'])
69
70 libocsrm_env.AppendUnique(LIBPATH = [libocsrm_env.get('BUILD_DIR')])
71 libocsrm_env.AppendUnique(LIBS = ['coap'])
72
73 if target_os == 'arduino':
74         libocsrm_env.AppendUnique(CPPDEFINES = ['NDEBUG', 'WITH_ARDUINO'])
75 elif target_os not in ['windows', 'msys_nt']:
76         libocsrm_env.AppendUnique(CFLAGS = ['-fPIC'])
77         libocsrm_env.AppendUnique(LIBS = ['m'])
78
79 if target_os in ['windows', 'msys_nt']:
80         libocsrm_env.AppendUnique(LIBPATH = [os.path.join(libocsrm_env.get('BUILD_DIR'), 'resource', 'oc_logger')])
81
82 if target_os in ['darwin', 'ios']:
83         libocsrm_env.AppendUnique(CPPDEFINES = ['_DARWIN_C_SOURCE'])
84         libocsrm_env.AppendUnique(LIBPATH = [libocsrm_env.get('BUILD_DIR')])
85         libocsrm_env.AppendUnique(LIBS = ['coap'])
86
87 if env.get('LOGGING'):
88         libocsrm_env.AppendUnique(CPPDEFINES = ['TB_LOG'])
89
90 if env.get('MULTIPLE_OWNER') == '1':
91         libocsrm_env.AppendUnique(CPPDEFINES=['MULTIPLE_OWNER'])
92
93 ######################################################################
94 # Source files and Targets
95 ######################################################################
96 OCSRM_SRC = 'src/'
97 libocsrm_src = [
98         OCSRM_SRC + 'secureresourcemanager.c',
99         OCSRM_SRC + 'resourcemanager.c',
100         OCSRM_SRC + 'aclresource.c',
101         OCSRM_SRC + 'verresource.c',
102         OCSRM_SRC + 'amaclresource.c',
103         OCSRM_SRC + 'amsmgr.c',
104         OCSRM_SRC + 'pstatresource.c',
105         OCSRM_SRC + 'doxmresource.c',
106         OCSRM_SRC + 'credresource.c',
107         OCSRM_SRC + 'svcresource.c',
108         OCSRM_SRC + 'pconfresource.c',
109         OCSRM_SRC + 'dpairingresource.c',
110         OCSRM_SRC + 'policyengine.c',
111         OCSRM_SRC + 'psinterface.c',
112         OCSRM_SRC + 'srmresourcestrings.c',
113         OCSRM_SRC + 'srmutility.c',
114         OCSRM_SRC + 'iotvticalendar.c',
115         OCSRM_SRC + 'base64.c',
116         OCSRM_SRC + 'directpairing.c'
117         ]
118
119 if libocsrm_env.get('SECURED') == '1':
120         libocsrm_src = libocsrm_src + [OCSRM_SRC + 'oxmpincommon.c', OCSRM_SRC + 'pbkdf2.c']
121         libocsrm_src = libocsrm_src + [OCSRM_SRC + 'crlresource.c', OCSRM_SRC + 'pkix_interface.c']
122         libocsrm_src = libocsrm_src + [OCSRM_SRC + 'oxmverifycommon.c']
123
124 if target_os in ['windows', 'msys_nt']:
125         libocsrm_src  = libocsrm_src + [OCSRM_SRC + 'strptime.c']
126
127
128 libocsrm_src.extend(env['cbor_files'])
129
130 # Insert a hack for Arduino, whose compiler may not support all defines expected
131 # by tinycbor
132 if target_os in ['arduino']:
133         libocsrm_env.AppendUnique(CPPDEFINES = ['INT64_MAX=0x7FFFFFFFFFFFFFFF'])
134
135 libocsrm_conf = Configure(libocsrm_env)
136 if libocsrm_conf.CheckFunc('strptime'):
137         libocsrm_conf.env.AppendUnique(CPPDEFINES = ['HAVE_STRPTIME'])
138 libocsrm_env = libocsrm_conf.Finish()
139
140 libocsrm = libocsrm_env.StaticLibrary('ocsrm', libocsrm_src)
141
142 libocsrm_env.InstallTarget(libocsrm, 'ocsrm')
143
144 if target_os in ['linux', 'android', 'tizen', 'msys_nt', 'windows'] and libocsrm_env.get('SECURED') == '1':
145         SConscript('provisioning/SConscript')
146
147 if target_os in ['linux', 'windows', 'darwin'] and libocsrm_env.get('SECURED') == '1':
148         SConscript('tool/SConscript')