9a6fced957639c229505e3d3350a94252a7cb51a
[iotivity.git] / resource / csdk / SConscript
1 #******************************************************************
2 #
3 # Copyright 2014 Intel Mobile Communications GmbH All Rights Reserved.
4 #
5 #-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
6 #
7 # Licensed under the Apache License, Version 2.0 (the "License");
8 # you may not use this file except in compliance with the License.
9 # You may obtain a copy of the License at
10 #
11 #      http://www.apache.org/licenses/LICENSE-2.0
12 #
13 # Unless required by applicable law or agreed to in writing, software
14 # distributed under the License is distributed on an "AS IS" BASIS,
15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
16 # See the License for the specific language governing permissions and
17 # limitations under the License.
18 #
19 #-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
20
21 ##
22 # liboctbstack (share library) build script
23 ##
24 Import('env')
25
26 lib_env = env.Clone()
27 SConscript(env.get('SRC_DIR') + '/resource/third_party_libs.scons', 'lib_env')
28
29 liboctbstack_env = lib_env.Clone()
30
31 target_os = env.get('TARGET_OS')
32 # As in the source code, it includes arduino Time library (C++)
33 # It requires compile the .c with g++
34 if target_os == 'arduino':
35         liboctbstack_env.Replace(CC = env.get('CXX'))
36         liboctbstack_env.Replace(CFLAGS = env.get('CXXFLAGS'))
37
38 ######################################################################
39 # Build flags
40 ######################################################################
41 liboctbstack_env.PrependUnique(CPPPATH = [
42                 '../../extlibs/cjson/',
43                 '../../extlibs/timer/',
44                 'logger/include',
45                 'ocrandom/include',
46                 'ocmalloc/include',
47                 'stack/include',
48                 'stack/include/internal',
49                 '../oc_logger/include',
50                 'connectivity/lib/libcoap-4.1.1',
51                 'connectivity/inc',
52                 'connectivity/api',
53                 'security/include',
54                 'security/include/internal',
55                 ])
56
57 if target_os not in ['arduino', 'windows', 'winrt']:
58         liboctbstack_env.AppendUnique(CPPDEFINES  = ['WITH_POSIX'])
59         liboctbstack_env.AppendUnique(CFLAGS = ['-std=c99'])
60
61 if target_os not in ['windows', 'winrt']:
62         liboctbstack_env.AppendUnique(CFLAGS = ['-Wall'])
63
64 liboctbstack_env.AppendUnique(LIBPATH = [env.get('BUILD_DIR')])
65
66 if target_os in ['android', 'linux']:
67         liboctbstack_env.AppendUnique(LIBS = ['connectivity_abstraction'])
68 liboctbstack_env.AppendUnique(LIBS = ['coap', 'm'])
69
70 if target_os not in ['android', 'arduino', 'windows', 'winrt']:
71         liboctbstack_env.AppendUnique(LIBS = ['pthread'])
72
73 if target_os == 'arduino':
74         liboctbstack_env.AppendUnique(CPPDEFINES = ['NDEBUG', 'WITH_ARDUINO'])
75 elif target_os not in ['darwin','ios']:
76         liboctbstack_env.AppendUnique(CFLAGS = ['-fPIC'])
77 if target_os in ['darwin', 'ios']:
78         liboctbstack_env.AppendUnique(CPPDEFINES = ['_DARWIN_C_SOURCE'])
79         liboctbstack_env.AppendUnique(LIBPATH = [env.get('BUILD_DIR')])
80 if target_os not in ['arduino']:
81         liboctbstack_env.AppendUnique(LINKFLAGS = ['-Wl,--no-undefined'])
82
83 if env.get('SECURED') == '1':
84         liboctbstack_env.AppendUnique(LIBS = ['tinydtls'])
85
86 if env.get('LOGGING'):
87         liboctbstack_env.AppendUnique(CPPDEFINES = ['TB_LOG'])
88
89 ######################################################################
90 # Source files and Targets
91 ######################################################################
92 OCTBSTACK_SRC = 'stack/src/'
93 liboctbstack_src = [
94         '../../extlibs/cjson/cJSON.c',
95         '../../extlibs/timer/timer.c',
96         OCTBSTACK_SRC + 'ocstack.c',
97         OCTBSTACK_SRC + 'occlientcb.c',
98         OCTBSTACK_SRC + 'ocresource.c',
99         OCTBSTACK_SRC + 'ocobserve.c',
100         OCTBSTACK_SRC + 'ocserverrequest.c',
101         OCTBSTACK_SRC + 'occollection.c',
102         OCTBSTACK_SRC + 'oicgroup.c',
103         'security/src/ocsecurity.c',
104         'logger/src/logger.c',
105         'ocrandom/src/ocrandom.c',
106         'ocmalloc/src/ocmalloc.c'
107         ]
108 if target_os in ['arduino','darwin','ios'] :
109         static_liboctbstack = liboctbstack_env.StaticLibrary('octbstack', liboctbstack_src)
110         liboctbstack_env.InstallTarget(static_liboctbstack, 'liboctbstack')
111 else:
112         static_liboctbstack = liboctbstack_env.StaticLibrary('octbstack', liboctbstack_src)
113         shared_liboctbstack = liboctbstack_env.SharedLibrary('octbstack', liboctbstack_src)
114         liboctbstack_env.InstallTarget([static_liboctbstack, shared_liboctbstack], 'liboctbstack')
115