Fix memory leak
[iotivity.git] / SConstruct
1 #******************************************************************
2 #
3 # Copyright 2014 Intel Mobile Communications GmbH All Rights Reserved.
4 #
5 #-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
6 #
7 # Licensed under the Apache License, Version 2.0 (the "License");
8 # you may not use this file except in compliance with the License.
9 # You may obtain a copy of the License at
10 #
11 #      http://www.apache.org/licenses/LICENSE-2.0
12 #
13 # Unless required by applicable law or agreed to in writing, software
14 # distributed under the License is distributed on an "AS IS" BASIS,
15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
16 # See the License for the specific language governing permissions and
17 # limitations under the License.
18 #
19 #-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
20
21 ##
22 # The main build script
23 #
24 ##
25 import os
26 import sys
27 import SCons
28 print("Processing using SCons version " + SCons.__version__)
29 print('Python '+ sys.version.replace('\n','') + ' on '+sys.platform)
30
31 # Load common build config
32 SConscript('build_common/SConscript')
33
34 # The construction environment named 'env' is set up in build_common
35 # and should be imported by all other scripts which need access to it.
36 # Scripts which do not need to modify the global construction environment
37 # should Clone() this environment and modify the clone.
38 # Scripts which need to modify the global environment should not
39 # work on a clone, since those changes will not propagate.
40 # Normally global changes should be limited to build_common and
41 # the extlibs scripts.
42 Import('env')
43
44 if os.environ.get('TERM') is not None:
45     env['ENV']['TERM'] = os.environ['TERM']
46
47 # Load extra options
48 SConscript('extra_options.scons')
49
50 target_os = env.get('TARGET_OS')
51
52 # By default, src_dir is the current dir, build_dir is:
53 #     ./out/<target_os>/<target_arch>/<release or debug>/
54 #
55 # The build_dir is a Variant directory of the source directory.
56 # iotivity variant directories are set up with argument "duplicate=0",
57 # which means build_dir files will behave like soft links to src_dir files.
58 # For more reading on this:
59 #     http://www.scons.org/doc/production/HTML/scons-user.html#f-VariantDir
60 #
61 # Any way, to make the output is in build_dir, when load scripts, the path should
62 # be relevant to build_dir.
63 build_dir = env.get('BUILD_DIR')
64
65 # Build 'resource' sub-project
66 SConscript(build_dir + 'resource/SConscript')
67
68 if target_os not in ['darwin','ios', 'android', 'msys_nt', 'windows']:
69     SConscript(build_dir + 'examples/OICMiddle/SConscript')
70     if env.get('SECURED') == '1':
71         SConscript(build_dir + 'examples/OCFSecure/SConscript')
72
73 java_build = None
74 if (env.get('BUILD_JAVA') and env.get('JAVA_HOME')) or target_os == 'android':
75     java_build = SConscript(build_dir + 'java/SConscript')
76
77 # Build 'service' sub-project
78 service_build = SConscript(build_dir + 'service/SConscript')
79
80 if java_build:
81     Depends(service_build, java_build)
82
83 # Build other sub-projects
84 SConscript(dirs=[
85     build_dir + 'cloud',
86     build_dir + 'plugins',
87     build_dir + 'bridging',
88 ])
89
90 # Append target information to the help information (if needed)
91 # To see help info, execute:
92 #     $ scons [options] -h
93 # Note some help is option-dependent, e.g. java-related options are
94 # not added to the help unless BUILD_JAVA is seen
95 #
96 # This is not really needed unless requesting help, consider adding check:
97 #if env.GetOption('help'):
98 env.PrintTargets()
99
100 # to install the generated pc file into custom prefix location
101 env.UserInstallTargetPCFile('iotivity.pc', 'iotivity.pc')